Hâc, Hâc. Io cu cine votez?

Încerc să-mi revin după ghioaga primită drept în moalele capului, de la prea-onorabilii noștri aleși. Cine nu știe despre ce-i vorba, îi invit să ia aminte și să citească cu mare atenție articolul lui Dan Tapalagă.

După cum se poate observa citind pe site-ul Camerei Deputaților, a fost un vot masiv în favoarea acestei mârșăvii fără margini.

Am avut o curiozitate personală. Cine sunt deputații aleși în circumscripțiile din Iași, care nu au avut nici cea mai mică problemă să voteze (cu ambele mâini dacă se poate) această cretinătate de lege. Iată răspunsul:

set serveroutput on
set define off
declare
  MAIN_ADDR constant varchar2(100) := 'http://www.cdep.ro';
  l_xml clob;
  l_dep_iasi dbms_sql.varchar2_table;

  function deputati_iasi return dbms_sql.varchar2_table as
    req   utl_http.req;
    resp  utl_http.resp;
    value varchar2(1024);
    idx   pls_integer := 1;
    c     dbms_sql.varchar2_table;
  begin
    req := utl_http.begin_request(MAIN_ADDR || '/pls/parlam/structura.ce?cir=24&leg=2012&prn=1');
    resp := utl_http.get_response(req);
    loop
      utl_http.read_line(resp, value, true);
      if regexp_like(value, '/pls/parlam/structura.mp\?idm=') then
        c(idx) := regexp_replace(value, '.*>([^>]+)<.*', '\1');
        idx := idx + 1;
      end if;
    end loop;
    utl_http.end_response(resp);
    return c;
  exception
    when utl_http.end_of_body then
      utl_http.end_response(resp);
      return c;
  end;

  function get_vot_rusinos return clob as
    req   utl_http.req;
    resp  utl_http.resp;
    value varchar2(1024);
    c     clob;
  begin
    req := utl_http.begin_request(MAIN_ADDR || '/pls/steno/evot.xml?par1=2&par2=11386');
    resp := utl_http.get_response(req);
    loop
      utl_http.read_line(resp, value, true);
      c := c || value || chr(10);
    end loop;
    utl_http.end_response(resp);
    return c;
  exception
    when utl_http.end_of_body then
      utl_http.end_response(resp);
      return c;
  end;

begin
  l_xml := get_vot_rusinos;
  l_dep_iasi := deputati_iasi;
  for l_rec in (SELECT votid, nume, prenume, grup, vot
                  FROM XMLTABLE('/ROWSET/ROW'
                      PASSING xmltype(l_xml)
                  COLUMNS 
                          votid INTEGER PATH 'VOTID',
                          nume VARCHAR2(100) PATH 'NUME',
                          prenume VARCHAR2(500) PATH 'PRENUME',
                          grup VARCHAR2(100) PATH 'GRUP',
                          vot varchar2(30) path 'VOT') 
                        src) loop
    for i in l_dep_iasi.first .. l_dep_iasi.last loop
      if l_dep_iasi(i) = (l_rec.nume || ' ' || l_rec.prenume) and l_rec.vot = 'DA' then
        dbms_output.put_line(l_dep_iasi(i) || ' (' || l_rec.grup || ')' || ' => ' || 'RUSINEEE!!!');
      end if;
    end loop;
  end loop;
end;
/

Rulând acest cod, obținem rezultatul de mai jos:

Stanciu Anghel (PSD) => RUSINEEE!!!
Craciunescu Grigore (PNL) => RUSINEEE!!!
Mocanu Vasile (PSD) => RUSINEEE!!!
Oajdea Daniel Vasile (PP-DD) => RUSINEEE!!!
Ratoi Neculai (PSD) => RUSINEEE!!!
Manolescu Oana (Mino.) => RUSINEEE!!!
Fenechiu Relu (PNL) => RUSINEEE!!!
Emacu Gheorghe (PSD) => RUSINEEE!!!
Stancu Ionel (Mino.) => RUSINEEE!!!
Adascalitei Constantin (PSD) => RUSINEEE!!!
Iacoban Sorin-Avram (PSD) => RUSINEEE!!!
Alexe Costel (PNL) => RUSINEEE!!!
Nichita Cristina (PSD) => RUSINEEE!!!

Felicitări și la mai mare!

PS 1:

• Site-ul Camerei Deputaților arată jalnic. Zici că e făcut de un student/elev care abia învață HTML. Varză! Multe coloane după care nu poți sorta, un design îngrozitor.
• S-ar parea că băieții au în spate o bază de date Oracle, mai ales dacă ne uităm la formatul XML de aici.
• Simpaticii folosesc și ceva de Oracle Application/HTTP Server. Dacă ne uităm în header-ul HTTP de răspuns găsim: "Oracle-Application-Server-10g/10.1.3.5.0 Oracle-HTTP-Server".

PS 2:
Doresc să o felicit din suflet și pe doamna Manolescu Oana, de la Asociația Liga Albanezilor din România. Taică-meu primește lună de lună "spam" de la ei pentru că bunicu' a fost albanez și cei de la ALAR, cumva, încearcă să păstreze legătura cu cei care mai au de-a face, încă, cu această comunitate. Doamnă, poate în următorul număr al revistei SPAM ne veți explica mai detaliat rațiunea votului dumneavoastră. Dacă se poate...